Chapter 16	Line and Surface Integrals

Useful Tip: If you are reading the electronic version of this publication formatted as a Mathematica Notebook, then it is possible to view 3-D plots generated by Mathematica from different perspectives.  First, place your screen cursor over the plot.  Then drag the mouse while pressing down on the left mouse button to rotate the plot.

16.1  Vector Fields

Students should read Section 16.1 of Rogawski's Calculus [1] for a detailed discussion of the material presented in this section.

Let (Subscript[F, 1]), (Subscript[F, 2]), and (Subscript[F, 3]) be functions of x, y, and z. The vector-valued function

F(x,y,z)=⟨(Subscript[F, 1])(x,y,z),(Subscript[F, 2])(x,y,z),(Subscript[F, 3])(x,y,z)⟩

is called a vector field. We have already encountered a vector field in the form of the gradient of a function. Other useful examples of vector fields are the gravitational force, the velocity of fluid, magnetic fields, and electric fields.

We use the Mathematica commands VectorFieldPlot and VectorFieldPlot3D to plot the graphs of vector fields.  However, before using these commands, it is advisable to load the VectorFieldPlots package. This is done by evaluating

Needs["VectorFieldPlots`"]

Example 16.1.  Draw the following vector fields.
a) F(x,y)=⟨sin y,cos x⟩ 	b)   F(x,y,z)=⟨y, x+z,2x-y⟩

Solution:
a)

Clear[F,x,y,z]
 F[x_,y_]={Sin[y],Cos[x]}

VectorFieldPlot[F[x,y],{x, -5,5},{y,-4,4},ImageSize->{250} ]

Here is another display of the preceding vector field with some options specified.

VectorFieldPlot[F[x,y],{x, -5,5},{y,-4,4},Axes->True,AxesOrigin ->{0,0},Frame->False,ColorFunction->Hue,ImageSize->{250}]

To see other available options of VectorFieldPlot, evaluate the command Options[VectorFieldPlot].

b) We shall use two of the options of VectorFieldPlot3D, which does not have as many options as VectorFieldPlot. (Again, you can find these by evaluating Options[VectorFieldPlot3D].)

Clear[F,x,y,z]
F[x_,y_,z_]={y (z^2),x (z^2),2 x y z}
VectorFieldPlot3D[F[x,y,z],{x,-3,3},{y,-3,3},{z,-3,3},ColorFunction->Hue,VectorHeads->True,ImageSize->{250}]

Example 16.2.  Draw the unit radial vector fields:
a) F(x,y)=⟨(x/(Sqrt[(x^2)+(y^2)])),(y/(Sqrt[(x^2)+(y^2)]))⟩	b)   F(x,y,z)=⟨(x/(Sqrt[(x^2)+(y^2)+(z^2)])),(y/(Sqrt[(x^2)+(y^2)+(z^2)])),(z/(Sqrt[(x^2)+(y^2)+(z^2)]))⟩

Solution: For convenience, we define both vector fields to be 0 at the origin. We shall use the If command to do so.

a)

Clear[F,x,y]
F[x_,y_]=If[(x^2)+(y^2)≠0,(({x,y})/(Sqrt[(x^2)+(y^2)])),{0,0}]
VectorFieldPlot[F[x,y],{x,-3,3},{y,-3,3},ImageSize->{250}]

b)

Clear[F,x,y,z]
F[x_,y_,z_]=If[(x^2)+(y^2)+(z^2)≠0,(({x,y,z})/(Sqrt[(x^2)+(y^2)+(z^2)])),{0,0,0}]
VectorFieldPlot3D[F[x,y,z],{x,-3,3},{y,-3,3},{z,-3,3},ColorFunction->Hue,VectorHeads->True,ImageSize->{250}]

Exercises

In Exercise 1 through 4, draw the given vector fields.
1.   F(x,y)=⟨ (y^2)-2xy, xy+6(x^2)⟩			2.   F(x,y,z)=⟨sin x,cos y ,xz⟩   
3.   F(x,y)=⟨  -(y/(Sqrt[(x^2)+(y^2)])),(x/(Sqrt[(x^2)+(y^2)]))⟩			4,   F(x,y,z)=⟨ x+cos (xz),y sin (xy),xz cos (yz) ⟩

In Exerices 5 and 6, calculate and plot the gradient vector field for each of the following functions.
5.   f(x,y)=ln(x+(y^2))				 6.  f(x,y,z)=sin x  (cos z/y)

16.2  Line Integrals

Students should read Section 16.2 of Rogawski's Calculus [1] for a detailed discussion of the material presented in this section.

Suppose C is a smooth curve in space whose parametric equations are given by

x=x(t), y=y(t),  z=z(t)

where a≤t≤b.  Let (Subscript[C, 1]), (Subscript[C, 2]), (Subscript[C, 3]), .... , (Subscript[C, N]) be a partition of the curve C with arc length (Subscript[Δs, 1]), (Subscript[Δs, 2]), (Subscript[Δs, 3]), ...  , (Subscript[Δs, N]) and let (Subscript[P, 1]), (Subscript[P, 2]), (Subscript[P, 3]), ... , (Subscript[P, N]) be points on the subarcs.

If f(x,y,z) is a function that is continuous on the curve C, then the line integral of f is defined by

(∫_C)f(x,y,z)ds=(lim_((Subscript[Δs, i])->0))(∑_(i=1)^N)f((Subscript[P, i]))(Subscript[Δs, i])

NOTE: If c(t)=⟨x(t), y(t),z(t)⟩ is the vector equation of the curve C, then it can be shown (refer to your calculus textbook) that

(∫_C)f(x,y,z)ds=(∫_a^b)f(c(t)‖c'(t)‖dt

In addition, if F(x,y,z)=⟨(Subscript[F, 1]),(Subscript[F, 2]),(Subscript[F, 3])⟩ is a vector field that is continuous on C, then the line integral of F over C is given by

(∫_C)F(x,y,z)·ds=(∫_C)(F·T)ds=(∫_a^b)F(c(t))·c'(t)dt

where T is the unit vector T=((c'(t))/(‖c'(t)‖)) and F·T is the dot product of F and T.

Example 16.3.  Find  (∫_C)f(x,y,z)ds, where f(x,y,z)=x y+(z^2) and C is given by  x= t, y= (t^2), and z=(t^3), for 0≤t≤1.

Solution:

Clear[x,y,z,t,f,c]
f[x_,y_,z_]=((x )^2)y+x z
x[t_]=t
y[t_]=(t^2)
z[t_]=(t^3)
c[t_]={x[t],y[t],z[t]}

(∫_0^1)f[x[t],y[t],z[t]]Norm[c'[t]]\[DifferentialD]t

Here is a numerical approximation of the preceding line integral.

NIntegrate[f[x[t],y[t],z[t]]Norm[c'[t]],{t,0,1}]

Example 16.4.  Find  (∫_C)F(x,y,z)·ds, where F(x,y,z)=⟨ x  z, z (y^2), y (x^2)⟩ and the curve C is given by  x= 2t, y= sin t, and z=cos t, 0≤t≤2π.

Solution:

Clear[x,y,z,t,f,c]
F[x_,y_,z_]={x z,z (y^2), y (x^2)} 
x[t_]=2t 
y[t_]= Sin[t]
z[t_]=Cos[t]
c[t_]={x[t],y[t],z[t]}

(∫_0^(2Pi))F[x[t],y[t],z[t]].c'[t]\[DifferentialD]t

N[%]

Exercises

1.  Find  (∫_C)f(x,y,z)ds, where:
a.  f(x,y,z)= x (y^(2 ))-4 zy and C is given by  x= 2t, y= (t^(2/3)), and z=1-3(t^2), for 0≤t≤1.
b.  f(x,y,z)=(yz/x) and C is given by  x= ln t, y= (t^2), and z=3t, for 3≤t≤5.

2.   Find  (∫_C)F(x,y)·ds, where:
a.   F(x,y)=⟨ (e^(3x-2y)),(e^(2x+3y))⟩ and C is given by  x= 2t, y= sin t,  0≤t≤ π
b.  F(x,y)=⟨(x^2),yx+(y^2)⟩ and C is the unit circle center at the origin.

3.  Find  (∫_C)F(x,y,z)·ds, where:
a.   F(x,y,z)=⟨xyz,-xz,xy ⟩ and C is given by  x= t, y= 2(t^2), z=3t  0≤t≤ 1
b.   F(x,y,z)=⟨(xy^3),z+(x^2),(z^3)⟩ and C is the line segment joining (-1,2,-1) and (1, 3, 4).

16.3  Conservative Vector Fields

Students should read Section 16.3 of Rogawski's Calculus [1] for a detailed discussion of the material presented in this section.

Let F(x,y,z)=⟨(Subscript[F, 1]),(Subscript[F, 2]),(Subscript[F, 3])⟩ be a vector field. Let (Subscript[C, 1]) and (Subscript[C, 2]) be any two different curves with the same initial point P and end point Q.  We say that the vector field F is path independent if

(Subscript[(∫_C), 1])F(x,y,z)·ds=(Subscript[(∫_C), 2])F(x,y,z)·ds

A vector field that is path independent is called conservative.

NOTE 1: A vector field F is conservative if

(∫_C)F(x,y,z)·ds=0

for every closed curve C.

NOTE 2: If F=∇u is the gradient of a function u=u(x,y,z), then we say that u is the potential of F.  Moreover, if the end points of C are P and Q, we have

(∫_C)F(x,y,z)·ds=u(P)-u(Q)

In particular, if the curve is closed, that is, if P=Q, then

(∫_C)F(x,y,z)·ds=0

Therefore, gradient is conservative. The converse of this statement is true if its domain is an open connected domain.

NOTE 3: Let F=⟨(Subscript[F, 1]),(Subscript[F, 2])⟩.  If F=∇u=⟨((∂ u)/(∂ x)),((∂ u)/(∂ y))⟩, then (Subscript[F, 1])=((∂ u)/(∂ x)) and (Subscript[F, 2])=((∂ u)/(∂ y)). Taking the partial derivative of (Subscript[F, 1])with respect to y and that of (Subscript[F, 2]) with respect to x and using the fact that (((∂^2) u)/(∂ x∂ y))=(((∂^2) u)/(∂ y∂ x)), we see that (Subscript[F, 1]) and (Subscript[F, 2]) must satisfy

((∂ (Subscript[F, 1]))/(∂ y))=((∂ (Subscript[F, 2]))/(∂ x))

This equation is used to check if a vector field is conservative.  In that case, we solve (Subscript[F, 1])=((∂ u)/(∂ x)) for u by integrating with respect to x and then use the equation (Subscript[F, 2])=((∂ u)/(∂ y)) to find the constant of integration. Here is an example.

Example 16.5.  Show that the vector function F=⟨3(x^2)-2xy +2,6(y^2)-(x^2)+3⟩  is conservative and find its potential.

Solution: Here, (Subscript[F, 1])=x (y^2) and (Subscript[F, 2])=(x^2)y. We now compare ((∂ (Subscript[F, 1]))/(∂ y)) and ((∂ (Subscript[F, 2]))/(∂ x)) to verify if F is conservative.

Clear[x,y,F1,F2]
F1[x_,y_]= 3(x^2)-2x y+2
F2[x_,y_]=6(y^2)-(x^2)+3

D[F1[x,y],y]
D[F2[x,y],x]

Thus, the vector field is conservative. To find its potential u, we integrate (Subscript[F, 1])=((∂ u)/(∂ x)) with respect to x to get

Clear[h,u]
u=Integrate[F1[x,y],x] +h[y]

Note that the addition of h(y) is necessary because the constant of integration may depend on y.  We now solve the equation (Subscript[F, 2])=((∂ u)/(∂ y)) for h'(y).

Clear[sol]
sol=Solve[D[u,y]==F2[x,y],h'[y]]

This means that h'(y)=3(1+2(y^2)).

Integrate[sol[[1,1,2]],y]

Hence, h(y)=3y+2(y^2)  and so u(x,y)=2x+(x^3)-(x^2) y +3y+2(y^3) is the potential of F.

NOTE 4: Let F=⟨(Subscript[F, 1]),(Subscript[F, 2]),(Subscript[F, 3])⟩.  If F=∇u=⟨((∂ u)/(∂ x)),((∂ u)/(∂ y)),((∂ u)/(∂ z))⟩, then (Subscript[F, 1])=((∂ u)/(∂ x)), (Subscript[F, 2])=((∂ u)/(∂ y)) and (Subscript[F, 3])=((∂ u)/(∂ z)). Taking the partial derivative of (Subscript[F, 1])with respect to y and that of (Subscript[F, 2]) with respect to x and using the fact that (((∂^2) u)/(∂x∂y))=(((∂^2) u)/(∂y∂x)), we see that (Subscript[F, 1]) and (Subscript[F, 2]) must satisfy

((∂ (Subscript[F, 1]))/(∂ y))=((∂ (Subscript[F, 2]))/(∂ x))

Taking the partial derivative of (Subscript[F, 1])with respect to z and that of (Subscript[F, 3]) with respect to x and using the fact that (((∂^2) u)/(∂x∂z))=(((∂^2) u)/(∂z∂x)), we see that (Subscript[F, 1]) and (Subscript[F, 3]) must satisfy

((∂ (Subscript[F, 1]))/(∂ z))=((∂ (Subscript[F, 3]))/(∂ x))

The preceding two equations can be used to check if a vector field is conservative. If this the case, we solve (Subscript[F, 1])=((∂ u)/(∂ x)) for u by integrating with respect to x and then use (Subscript[F, 2])=((∂ u)/(∂ y)) to find the constant of integration. We show this by the following example.

Example 16.6.  Show that the vector function F=⟨yz+yz cos (xy ), xz+xz cos (xy) ,xy+sin (xy)⟩  is conservative and find its potential.

Solution: Here, (Subscript[F, 1])=y z+y z cos( x y) ,  (Subscript[F, 2])=x z +x z cos (x y),  and (Subscript[F, 3])=x y + sin(x y) .

Clear[x,y,F1,F2,F3]
F1[x_,y_,z_]= y z +y z Cos[x y]
F2[x_,y_,z_]= x z + x z Cos[x y]
F3[x_,y_,z_]= x y +  Sin[x y]

We now compare ((∂ (Subscript[F, 1]))/(∂ y)) and ((∂ (Subscript[F, 2]))/(∂ x)):

D[F1[x,y,z],y]
D[F2[x,y,z],x]

Next, we compare ((∂ (Subscript[F, 1]))/(∂ z)) and ((∂ (Subscript[F, 2]))/(∂ x)):

D[F1[x,y,z],z]
D[F3[x,y,z],x]

Thus, the vector field is conservative. To find its potential u, we integrate (Subscript[F, 1])=((∂ u)/(∂ x)) with repsetct to x to get

Clear[u, h]
u=Integrate[F1[x,y,z],x] +h[y,z]

Note that the addition of h(y,z) is necessary because the constant of intgeration can depend on y and z. We now solve the equation (Subscript[F, 2])=((∂ u)/(∂ y)) for ((∂ h)/(∂ y)).

Clear[sol]
sol=Solve[D[u,y]==F2[x,y,z],(∂_y) h[y,z]]

This means that ((∂ h)/(∂ y))=0 and hence h is a function of z only.   Next, we solve the equation (Subscript[F, 3])=((∂ u)/(∂ z)) for ((∂ h)/(∂ z)).

Clear[sol2]
sol2=Solve[D[u,z]==F3[x,y,z],(∂_z) h[y,z]]

Hence, ((∂ h)/(∂ z))=0 and we can take h=0. Therefore, u=x y z +z sin (x y) is the potential for the vector field F.

Exercises

1. Show that the vector field F=⟨ (y^3)-3(x^2)y, 3(xy^2)-(x^3)⟩  is conservative and find its potential.

2. Show that the vector field F=⟨y z+((2 xy)/z), xz+((x^2)/z), xy-(((x^2)y)/(z^2))⟩  is conservative and find its potential.

3. Determine whether the vector field F=⟨(x^2), yx +(e^z), y (e^z)⟩  is conservative.  If it is, find its potential.

16.4  Parametrized Surfaces and Surface Integrals

Students should read Section 16.4 of Rogawski's Calculus [1] for a detailed discussion of the material presented in this section.

A parametrized surface is a surface whose points are given in the form

G(u,v)=(x(u,v), y(u,v), z(u,v))

where u and v (called parameters) are independent variables used to describe a domain D (called the parameter domain).

The command for plotting parametrized surfaces is ParametricPlot3D.  This command has been discussed in Section 14.1.2 of this text.

Example 16.7.  Plot the parametrized surface defined by G(u,v)=(cos u sin v, 4 sin u cos v, cos v) over the domain D={(u,v)| 0≤u≤2π, 0≤v≤2π}.

Solution:

ParametricPlot3D[{ Cos[u] Sin[v],4 Sin[u] Cos[v], Cos[v]},{u,0,2Pi},{v,0,2Pi},ImageSize->{250}]

Example 16.8.  Plot the parametrized surface defined by G(u,v)=(u cos v,u sin v,1-(u^2)) over the domain D={(u,v)|0≤u≤1,0≤v≤2π}.

Solution:

ParametricPlot3D[{u Cos[v]  ,u Sin[v]  , 1-(u^2)},{u,0,1},{v,0,2Pi},ColorFunction->"BlueGreenYellow",ImageSize->{250},
ImagePadding->{{15,15},{15,15}}]

NOTE: On a parametrized surface G(u,v)=(x(u,v), y(u,v), z(u,v)), if we fix one of the variables, we get a curve on the surface.  The plot following shows the curves corresponding to u=3/4 (latitude) and v=5π/3 (longitude).

Clear[plot1,plot2,plot3] 
plot1= ParametricPlot3D[{u  Cos[v]  ,u Sin[v]  , 1-(u^2)},{u,0,1},{v,0,2Pi},ColorFunction->"BlueGreenYellow"];
plot2=ParametricPlot3D[{  3/4 Cos[v]  ,3/4  Sin[v]  , 7/16},{v,0,2Pi},PlotStyle->{Thickness[0.01],Red}];
plot3=ParametricPlot3D[{  u  Cos[5Pi/3]  ,u  Sin[5Pi/3]  ,1-(u^2)},{u,0,1},PlotStyle->{Thickness[0.01],Blue}];
Show[plot1,plot2,plot3,PlotRange->All,ImageSize->{250},
ImagePadding->{{15,15},{15,15}}]

Let P=G((Subscript[u, 0]),(Subscript[v, 0])) be a point on the parametrized surface S.  For fixed v=(Subscript[v, 0]), the tangent vector to the curve G(u,(Subscript[v, 0])) at ((Subscript[u, 0]),(Subscript[v, 0]))  is given by

(Subscript[T, u])=((∂G)/(∂u))((Subscript[u, 0]),(Subscript[v, 0]))

while the tangent vector for  G((Subscript[u, 0]),v) corresponding to a fixed u=(Subscript[u, 0]) is given by

(Subscript[T, v])=((∂G)/(∂v))((Subscript[u, 0]),(Subscript[v, 0]))

These two vectors are tangent to the surface S.  Thus, the normal vector n to the tangent plane at G((Subscript[u, 0]),(Subscript[v, 0])) is given by

n(P)=n((Subscript[u, 0]),(Subscript[v, 0]))=(Subscript[T, u])×(Subscript[T, v])

Example 16.9.  Consider the parametrized surface G(u,v)=( u cos v, u sin v, 1-(v^2)).
a) Find (Subscript[T, u]), (Subscript[T, v]), and n.
b) Find the equation of the tangent plane at (1/2, 5π/3).
c) Plot the tangent plane and surface.

Solution:  Let us define G as a function of u and v in Mathematica.

Clear[G,u,v]
G[u_,v_]={u Cos[v], u Sin[v], 1-(u^2)}

a) We use Tu for (Subscript[T, u]) and Tv for (Subscript[T, v]). We evaluate these as functions of u and v.

Clear[Tu,Tv,n]
Tu[u_,v_]=D[G[u,v],u]
Tv[u_,v_]=D[G[u,v],v]
n[u_,v_]=Cross[Tu[u,v],Tv[u,v]]

b) The normal vector to the tangent plane at (1/2, 5π/3) is

Clear[normal]
normal=n[1/2,5Pi/3]

The tangent plane passes through the point

Clear[point]
point=G[1/2,5Pi/3]

Thus, the equation of the tangent plane is given by

Clear[tplane]
tplane=normal.({x,y,z}-point)==0

which simplifies to

Simplify[tplane]

c) Here is the plot of the surface and the tangent plane. Observe that we have used ColorFunction and ColorFunctionScaling options.

Clear[plot1, plot2]
plot1= ParametricPlot3D[G[u,v],{u,0,1},{v,0,2Pi},ColorFunction->"BlueGreenYellow"];
plot2=ContourPlot3D[2 x+4 z==5+2 (Sqrt[3]) y, {x, -3,3}, {y, -3,3},{z, -4,4},ColorFunction->Function[{x,y,z},Hue[Mod[z,1]]],ColorFunctionScaling->False];
Show[plot1, plot2,ImageSize->{250},ImagePadding->{{15,15},{15,15}}]

NOTE: The area A(S) of a parametrized surface S: G(u,v)=(x(u,v), y(u,v), z(u,v)), where (u,v)∈D, is given by

A(S)=∫(∫_D)||n(u,v)||dudv

If f(x,y,z) is continuous at all points of S, then the surface area of f over S is given by

∫(∫_S)f(x,y,z)dS=∫(∫_D)f(G(u,v))||n(u,v)||dudv

Example 16.10.  Show the following:
a) The area of the cylinder of height h  and radius r is 2π rh.
b) The area of the sphere of radius r is 4π (r^2).

Solution: 
a) A parametric equation of the cylinder of height h  and radius r can be given by

x=r cos v, y=r sin v, and z=u, where  0≤v≤2π , 0≤u≤h

Thus, the cylinder is given by G(u,v)=(r cos u, r sin u, v).

Clear[ G,u,v,r]
G[u_,v_]={r Cos[v], r Sin[v],u}

Here is a plot of the cylinder with r=3 and h=5:

r=3;h=5;
ParametricPlot3D[G[u,v], {u, 0, h},{v, 0, 2Pi}]

To compute the surface area of the cylinder, we need to compute its normal vector.

Clear[Tu,Tv,n,r,h]
Tu[u_,v_]=D[G[u,v],u];
Tv[u_,v_]=D[G[u,v],v];
n[u_,v_]=Cross[Tu[u,v],Tv[u,v]]

Here is a plot of the cylinder with its normal vector for  r=3 and h=5:

r=3;h=5;
Clear[plot1,plot2]
plot1=ParametricPlot3D[G[u,v], {u, 0, h},{v, 0, 2Pi}];
plot2=VectorFieldPlot3D[n[u,v],{u,0,h},{v,-2Pi,2Pi},{z,-3,3},  VectorHeads->True,PlotPoints->15];
Show[plot1,plot2,ImageSize->{250}]
Clear[r,h]

The surface area is

SArea=(∫_0^h)(∫_0^(2Pi))Norm[n[u,v]]\[DifferentialD]v\[DifferentialD]u

Since r>0, |r|=r and hence the preceding output is 2π r h .

b) A parametric equation of the sphere of radius r is

x=r cos u sin v, y=r sin u sin v, z=r cos v

where 0≤u≤2π and 0≤v≤π.  Thus, the sphere is given by G(u,v)=(r cos u sin v,r sin u sin v,r cos v).

Clear[ G,u,v,r]
G[u_,v_]={r Cos[u] Sin[v], r Sin[u] Sin[v],r Cos[v]}

Here is a plot of the sphere with r=3.

r=3; 
ParametricPlot3D[G[u,v],{u, 0, 2Pi}, {v, 0, Pi},ImageSize->{250}]

To compute the surface area of the sphere, we need to compute its normal vector.

Clear[Tu,Tv,n,r]
Tu[u_,v_]=D[G[u,v],u];
Tv[u_,v_]=D[G[u,v],v];
n[u_,v_]=Cross[Tu[u,v],Tv[u,v]]

Here is a plot of the sphere with its normal vector for  r=3.

r=3;h=5;
Clear[plot1,plot2]
plot1=ParametricPlot3D[G[u,v],{u, 0, 2Pi}, {v, 0, h}];
plot2=VectorFieldPlot3D[n[u,v],{u,-2Pi,2Pi},{v,0,h},{z,-3,3},  VectorHeads->True,PlotPoints->10];
Show[plot1,plot2,ImageSize->{250}]
Clear[r,h]

The surface area is

SArea=(∫_0^Pi)(∫_0^(2Pi))Norm[n[u,v]]\[DifferentialD]u\[DifferentialD]v

For a real number r, the conjugate of r is r and hence the preceding output is 4π (r^2).

Example 16.11.  Consider the parametrized surface S defined by G(u,v)=( u cos v, u sin v, v), where 0≤u≤1, 0≤v≤2π.
a) Find the surface area of S.
b) Evaluate ∫(∫_S)xyzdS.

Solution:
a)

Clear[ G,u,v]
G[u_,v_]={u Cos[v], u Sin[v],v}

Clear[Tu,Tv,n]
Tu[u_,v_]=D[G[u,v],u]
Tv[u_,v_]=D[G[u,v],v]
n[u_,v_]=Cross[Tu[u,v],Tv[u,v]]

The surface area A(S) is given by

SArea=(∫_0^1)(∫_0^(2Pi))Norm[n[u,v]]\[DifferentialD]v\[DifferentialD]u

which is approximately equal to

N[%]

b) We define f:

Clear[f]
f[x_,y_,z_]=x y z

The surface integral of f is

(∫_0^1)(∫_0^(2Pi))f[G[u,v][[1]],G[u,v][[2]],G[u,v][[3]]]Norm[n[u,v]]\[DifferentialD]v\[DifferentialD]u

Or numerically,

N[%]

Exercises

1. Plot the parametrized surface G(u,v)=((e^u)sin v,(e^u) cos v,v) over the domain D={(u,v)| -1≤u≤1, 0≤v≤2π}.

2. Plot the parametrized surface G(u,v)=(3sin u cos v,sin u sin v,cos v+3 cos u) over the domain D={(u,v)| 0≤u≤2π, 0≤v≤2π}.

3. Consider the parametrized surface G(u,v)=((e^(-u))  cos v,(e^u)sin v,(e^u)cos v).
a.  Find (Subscript[T, u]), (Subscript[T, v]), and n.
b.  Find the equation of the tangent plane at (0, π/ 2).
c.  Plot the tangent plane and surface.

4. Consider the parametrized surface S: G(u,v)=( u-v ,3u+v,(u^2)-2 u v +6(v^2)), where 0≤u≤1, 0≤v≤1.
a.  Find the surface area of S. (Use NIntegrate for faster integration.)
b.  Evaluate ∫(∫_S)(3x+ 2(y^2)-  (z^2))dS.

16.5  Surface Integrals of Vector Fields

Students should read Section 16.5 of Rogawski's Calculus [1] for a detailed discussion of the material presented in this section.

An orientation of a surface S is a continuously varying choice of the unit normal vector (Subscript[e, n])(P) at each point of the surface.  Thus, (Subscript[e, n]) is given by either

(Subscript[e, n])(P)=((n(P))/(||n(P)||))   or   (Subscript[e, n])(P)=-((n(P))/(||n(P)||))

If F(x,y,z) is continuous at all points of a parametrized surface S, then the surface integral of F over S is given by

∫(∫_S)F·dS=∫(∫_S)(F·(Subscript[e, n]))dS

where (Subscript[e, n]) is the unit normal determined by an orientation. The surface integral of F is also called the flux of F across S.

The surface integral of F over a parametrized surface S given by G(u,v)=(x(u,v),y(u,v),z(u,v)), where (u,v)∈D, is given by

∫(∫_S)F·dS=∫(∫_S)(F·(Subscript[e, n]))dS =∫(∫_D)F(G(u,v))·n(u,v) dudv

Example 16.12.  Find  ∫(∫_S)F·dS, where F(x,y,z)=⟨x  z, z , y x⟩ and S is given by  G(u,v)=(u-(v^2),u v,(u^2)-v), 0≤u≤2, and 1≤v≤3.

Solution:

Clear[F,G,x,y,z,u,v]
F[x_,y_,z_]={x z, z, y x}
G[u_,v_]={u-(v^2), u v, (u^2)-v}

Clear[Tu,Tv,n]
Tu[u_,v_]=D[G[u,v],u]
Tv[u_,v_]=D[G[u,v],v]
n[u_,v_]=Cross[Tu[u,v],Tv[u,v]]

Flux=(∫_0^2)(∫_1^3)F[G[u,v][[1]],G[u,v][[2]],G[u,v][[3]]] .n[u,v]\[DifferentialD]v\[DifferentialD]u

Example 16.13.  Find  ∫(∫_S)F·dS, where F(x,y,z)=⟨(x^2), (z^2) , y+ (x^2)⟩ and S is the upper hemisphere (x^2)+(y^(2 ))+(z^2)=4 with outward normal orientation.

Solution:  First, we find the parametric equation of the cylinder. This can be given by x=2 cos u sin v, y=2 sin u sin v, and z=2cos v, where 0≤u≤2π and 0≤v≤π/2.

For the hemisphere to have the outward orientation, we note that n=(Subscript[T, v])×(Subscript[T, u]). With this in mind we compute the flux of F across S through the following steps.

Clear[F,G,x,y,z,u,v]
F[x_,y_,z_]={   (x^2), (z^2), (x^2)+y+(z^3)}
G[u_,v_]= { 2 Cos[u]Sin[v]  , 2 Sin[u] Sin[v]   , Cos[v] }

Clear[Tu,Tv,n]
Tu[u_,v_]=D[G[u,v],u]
Tv[u_,v_]=D[G[u,v],v]
n[u_,v_]=Cross[Tv[u,v],Tu[u,v]]

Flux=(∫_0^(Pi/2))(∫_0^(2Pi))F[G[u,v][[1]],G[u,v][[2]],G[u,v][[3]]] .n[u,v]\[DifferentialD]u\[DifferentialD]v

Exercises

1. Find ∫(∫_S)F·dS, where F(x,y,z)=⟨ (e^z),z,y x⟩ and S is given by G(u,v)=(u v,u-v,u),  0≤u≤2, and -1≤v≤1, and oriented by n=(Subscript[T, u])×(Subscript[T, v]).

2. Find  ∫(∫_S)F·dS, where F(x,y,z)= ⟨ z,x ,y ⟩ and S is the portion of the ellipsoid  ((x^2)/16)+((y^(2 ))/9)+((z^2)/4)=1 for which x≤0,   y≤0, and z≤0 with outward normal orientation.

3. Let S be given by G(u,v)=((1+v cos(u/2))cos u,(1+v cos(u/2))sin u , v sin (u/2) ),  0≤u≤2π, and ((-1)/2)≤v≤(1/2).
a. Plot the surface S. (S is an example of a Mobius strip.)
b. Find the surface area of S.
c. Evaluate ∫(∫_S)((x^2)+ 2(y^2)+3  (z^2))dS.
d. Find the intersection points of S and the xy-plane.
e. For each of the points on the intersection of S and the xy-plane, find the normal vector n.
f. Show that n varies continuously but that n(2π,0)=-n(u,0). (This shows that S is not orientable and hence it is impossible to integrate a vector field over S.)